!
!  Copyright (c) 2001
!  by CompuServe Interactive Services, Inc. Columbus, Ohio
!
!  The information in this software is subject to change without
!  notice and should not be construed as a commitment by CompuServe.
!
!  UUNet:
!       Connect to UUNet Global IP (GENIP/UUG)
!       Success:  returns %Success
!       Failure:  saves error msg in %FailureMsg and returns %Failure
!
!+V
! "4.0.6EXP"
!-V

CompuServe_NUA = "dial@uupops.net";
CompuServe_NPSW = "dial@uupops.net";
Tries = 5;
twice_tried = %FALSE;
on cancel goto Return_Cancel;

show "Connecting to UUNet Global IP";

send %CR;       ! First time through, send CR to Init node

Wait_UUNet:
	if Tries = 0 goto UUNet_Failure;
	Tries = Tries - 1;
	wait
		"Login:"        goto Send_Address,
		"Password:"     goto Send_Password,
		"failure"       goto Resend_Address,
		%mdm_Failure    goto Lost_Carrier,
		"Login Invalid" goto UUNet_Failure,
		"no connection:"goto UUNet_Failure,
		"reset"         goto UUNet_Failure,
		"Connect Failed"goto UUNet_Failure,
		"Unreachable"   goto UUNet_Failure,
		"Unavailable"   goto UUNet_Failure,
		"** Bad"	goto Resend_Address,
		"Host Name:"    goto Return_Success,
		"User ID:"      goto Sendto_Hostname,
		"connected"     goto Another_Try,
		"Connecting"    goto Another_Try
	until 50;

	send %CR;
	
	goto Wait_UUNet;

Another_Try:
	! Attempt to wake up the network.
	send %CR;
	Tries = Tries + 1;
	goto Wait_UUNet;
	
Resend_Address:
	if twice_tried = %TRUE goto Cserve_NUA_Failure;
	twice_tried = %TRUE;
	goto Wait_UUNet;

Send_Address:
	show "Sending CompuServe NUA...";
	send CompuServe_NUA & %CR;
	goto Wait_UUNet;

Send_Password:
	send CompuServe_NPSW & %CR;
	goto Wait_UUNet;

Sendto_Hostname:
	send "/HOST" & %CR;
	goto Return_Success;

Lost_Carrier:
	define %FailureMsg = "Modem connection lost";

UUNet_Failure:
	define %FailureMsg = "UUNet Global IP not responding";
	goto Return_Failure;

Cserve_NUA_Failure:
	define %FailureMsg = "UUNet Global IP not accepting NUA";

Return_Failure:
	exit %Failure;

Return_Cancel:
	exit %Cancel;

Return_Success:
	exit %Success;