!
!  Copyright (c) 1997
!  by CompuServe Incorporated, Columbus, Ohio
!
!  The information in this software is subject to change without
!  notice and should not be construed as a commitment by CompuServe.
!
!  FT-Connect:
!       Connect to France Telecom
!       Success:  returns %Success
!       Failure:  saves error msg in %FailureMsg and returns %Failure
!
!+V
! "4.0"
!-V

CompuServe_NUA = "196282595";
Tries = 5;
twice_tried = %FALSE;
on cancel goto Return_Cancel;

show "Verbindungsaufbau mit FT-Connect";


Wait_FTConnect:
	if Tries = 0 goto FTConnect_Failure;
	Tries = Tries - 1;
	if (Tries = 4) goto Send_Address; ! First time
	wait
		"France"        goto Send_Address,
		"TRANSPAC"      goto Send_Address,
		"ERROR"         goto Resend_Address,
		"LIB"           goto Resend_Address,
		"CLR"           goto Resend_Address,
		%mdm_Failure    goto FTConnect_Failure,
		"COM"           goto Return_Success
	until 80;

	send %CR;
	goto Send_Address;
	
Resend_Address:
	if twice_tried = %TRUE goto Cserve_NUA_Failure;
	twice_tried = %TRUE;

Send_Address:
	show "CompuServe-NUA wird übertragen...";
	send CompuServe_NUA & %CR;
	goto Wait_FTConnect;

FTConnect_Failure:
	define %FailureMsg = "FT-Connect antwortet nicht";
	goto Return_Failure;

Cserve_NUA_Failure:
	define %FailureMsg = "FT-Connect CompuServe-NUA wurde nicht akzeptiert";

Return_Failure:
	exit %Failure;

Return_Cancel:
	exit %Cancel;

Return_Success:
	exit %Success;